option ls=76 nocenter;
data bond;
  input ingot metal $ pres;
  datalines;
1   n   67.0 
1   i   71.9 
1   c   72.2 
2   n   67.5 
2   i   68.8 
2   c   66.4 
3   n   76.0 
3   i   82.6 
3   c   74.5 
4   n   72.7 
4   i   78.1 
4   c   67.3 
5   n   73.1 
5   i   74.2 
5   c   73.2 
6   n   65.8 
6   i   70.8 
6   c   68.7 
7   n   75.6 
7   i   84.9 
7   c   69.0 
;
                                     
proc mixed data=bond covtest cl method=type3;
   class ingot metal;
   model pres=metal / ddfm=kr;
   random ingot;
   ods select Type3 CovParms;
   ods output type3=type3;
run;
data est_var_ingot;
   merge type3(where=(source='ingot')
               rename=(ms=msingot df=dfingot))
         type3(where=(source='Residual')
               rename=(ms=mserror df=dferror));
   var_Ingot    = (msingot-mserror)/3;
    df_var_ingot = (var_ingot**2)/((((msingot/3)**2)/dfingot)+
                   (((mserror/3)**2)/dferror));
    low_var_ingot= df_var_ingot*var_ingot/cinv(.975,df_var_ingot);
    up_var_ingot = df_var_ingot*var_ingot/cinv(.025,df_var_ingot);
run;
proc print data=est_var_ingot;
  var msingot dfingot mserror dferror 
      var_ingot df_var_ingot
      low_var_ingot up_var_ingot;
TITLE ' Var(ingot) and confidence interval';

PROC PRINT DATA=type3;                  /* Newly added statement */
TITLE ' What is in type3 ODS output?';
run;