options nodate nonumber ps=60 ls=80;

title 'RPD -- Example 11.17 -- Diagnostics: Linthurst Data';

data linthurst (drop=obsnum);
infile 'linthurst.dat';
input obsnum loc $ type $ biomass salinity pH K Na Zn;
run;


/* Sec. 11.4 */

proc reg;
model biomass = salinity pH K Na Zn / r influence partial;   
   /* residual analysis, influence diagnostics, partial regr. leverage plots */
run;


/* Sec. 11.4.1 */

plot residual.*predicted. / nomodel nostat;   /* plot of e versus Yhat */
run;


plot student.*nqq. / nomodel nostat noline;   
   /* normal probability plot of standardized residuals */
run;


plot residual.*salinity / nomodel nostat;
run;


plot residual.*pH / nomodel nostat;
run;


plot residual.*K / nomodel nostat;
run;


plot residual.*Na / nomodel nostat;
run;


plot residual.*Zn / nomodel nostat;
run;


/* Sec. 11.4.2 */

plot h.*obs. / vref = 0.267 nomodel nostat;   /* leverages */
run;


plot cookd.*obs. / vref = 0.0889 nomodel nostat;   /* Cook's D */
run;


plot dffits.*obs. / vref = 0.73 -0.73 nomodel nostat;
run;


plot covratio.*obs. / vref = 1.4 0.6 nomodel nostat;
run;


/* Collinearity Diagnostics */

model biomass = salinity pH K Na Zn / vif;   /* variance inflation factors */
run;